이것이 얼마나 잘 작동하는지 궁금했기 때문에, 나는 그런 종류의 작품을 함께 해킹했습니다.

이전 답변에 대한 주석에서 언급 했듯이이 작업을 수행하는 유일한 방법은 공백으로 영역을 채우는 것입니다. 정확히 우리가하는 일입니다. 쓰기 전에이 공간을 제거하므로 다른 사람을 괴롭히지 않아야합니다.

이 예제는 마크 다운 파일 유형에 따라 매우 다릅니다!

부작용 :

• 텍스트를 복사하면 많은 공간이 복사됩니다
• 사용 $하고 End더 이상 작동하지 않습니다 (이 열 80로 이동) 예상대로와 키 등
  j과 k도 다른 동작합니다.
• 'list'활성화 되면 배경이 표시되지 않습니다
• 빈 줄이 완전히 작동하지 않으면 탭이나 4 개의 공백을 수동으로 추가해야합니다.
• … 아마도 더?

먼저 이것을 다음에 추가해야합니다 ~/.vim/after/syntax/markdown.vim.

syn clear markdownCodeBlock
syn region markdownCodeBlock start="    \|\t" end="$"
hi def markdownCodeBlock ctermbg=230 guibg=lightyellow

물론 원하는대로 색상을 조정할 수 있습니다. 😉

그런 다음 이것을 vimrc에 추가하십시오.

fun! MarkdownBlocks()
    fun! s:fill(line)
        " Remove all trailing whitespace
        let l:line = substitute(a:line, " *$", "", "")

        " Add trailing whitespace up to 'textwidth' length
        return l:line . repeat(' ', (&tw > 0 ? &tw : 80) - strdisplaywidth(l:line))
    endfun

    " Get all lines in a list
    let l:lines = getline(1, line('$'))

    " Map s:fill() to the lines that are a code block
    call map(l:lines, 'v:val[0] == "\t" || v:val[:3] == "    " ? s:fill(v:val) : v:val')

    " Reset the buffer to the lines
    call setline(1, l:lines)
endfun

" Remove all the trailing spaces
fun! MarkdownBlocksClean()
    let l:save_cursor = getpos(".")
    silent %s/^\(    \|\t\)\(.\{-}\)\( *\)$/\1\2/e
    call setpos('.', l:save_cursor)
endfun
au BufWritePre *.markdown call MarkdownBlocksClean()

" Set spaces on loading the file, leaving insert mode, and after writing it
au FileType markdown call MarkdownBlocks()
au InsertLeave *.markdown call MarkdownBlocks()
au BufWritePost *.markdown call MarkdownBlocks()

나는 코드를 한 줄씩 설명하지 않을 것이다.

답변

" Define a highlight group and a sign that uses it
highlight default markdownCodeBlock ctermbg=230 guibg=lightyellow
sign define codeblock linehl=markdownCodeBlock

" Use signs to highlight code blocks
function! MarkdownBlocks()
    function! s:applySign(idx, val)
        if a:val[0] == "\t" || a:val[:3] == "    "
            let l = a:idx + 1
            execute "sign place " . l . " line=" . l . " name=codeblock file=" . expand("%:p")
        endif
    endfunction

    " Remove old signs
    execute "sign unplace * file=" . expand("%:p")

    " Get all lines in a list
    let l:lines = getline(1, line('$'))
    " Add new signs
    call map(l:lines, function('s:applySign'))
endfunction

" Set signs on loading the file, leaving insert mode, and after writing it
au FileType markdown call MarkdownBlocks()
au InsertLeave *.markdown call MarkdownBlocks()
au BufWritePost *.markdown call MarkdownBlocks()