추출 된 파일을 가져 와서 서브 디렉토리로 이동하여 기본 폴더를 정리할 가능성이 있습니다.

    #!/usr/bin/perl -w

    use strict;
    use Getopt::Long;

    my $clean_folder = "clean";
    my $DRY_RUN;
    die "Usage: $0 [--dry] [--clean=dir-name]\n"
        if ( !GetOptions("dry!" => \$DRY_RUN,
                         "clean=s" => \$clean_folder));

    # Protect the 'clean_folder' string from shell substitution
    $clean_folder =~ s/'/'\\''/g;

    # Process the "tar tv" listing and output a shell script.
    print "#!/bin/sh\n" if ( !$DRY_RUN );
    while (<>)
    {
        chomp;

        # Strip out permissions string and the directory entry from the 'tar' list
        my $perms = substr($_, 0, 10);
        my $dirent = substr($_, 48);

        # Drop entries that are in subdirectories
        next if ( $dirent =~ m:/.: );

        # If we're in "dry run" mode, just list the permissions and the directory
        # entries.
        #
        if ( $DRY_RUN )
        {
            print "$perms|$dirent\n";
            next;
        }

        # Emit the shell code to clean up the folder
        $dirent =~ s/'/'\\''/g;
        print "mv -i '$dirent' '$clean_folder'/.\n";
    }

이것을 파일에 저장하십시오 fix-tar.pl 하고 다음과 같이 실행하십시오.

$ tar tvf myarchive.tar | perl fix-tar.pl --dry

tar목록이 내 것과 같다는 것을 확인합니다 . 다음과 같은 출력이 표시되어야합니다.

-rw-rw-r--|batch
-rw-rw-r--|book-report.png
-rwx------|CaseReports.png
-rw-rw-r--|caseTree.png
-rw-rw-r--|tree.png
drwxrwxr-x|sample/

그것이 좋아 보인다면 다음과 같이 다시 실행하십시오.

$ mkdir cleanup
$ tar tvf myarchive.tar | perl fix-tar.pl --clean=cleanup > fixup.sh

이 fixup.sh스크립트는 최상위 파일과 디렉토리를 “깨끗한”폴더 (이 경우 폴더)로 이동시키는 쉘 명령입니다 cleanup. 이 스크립트를 들여다보고 모든 것이 정결하다는 것을 확인하십시오. 그렇다면 다음과 같이 엉망을 정리할 수 있습니다.

$ sh fixup.sh

나는 이런 종류의 정리를 선호한다 tar xv.

참고 : 초기 드라이 런 출력이 올바르게 보이지 않으면 두 숫자를 사용하여 바이올린을 칠 수 있습니다. substr 함수 호출 적절 해 보일 때까지 . $perms변수는 그래서 정말에만 실행 건조에 사용되는 $dirent하위 문자열 요구에 적절한 될 수 있습니다.

또 다른 사항 : 목록 의 사용자 이름 및 / 또는 그룹 이름으로 인해 이름이 예측할 수없는 열로 시작하는 경우이 tar옵션 을 사용해야 할 수도 있습니다 .--numeric-ownertar

답변