나는 주로이 기능을 사용한다 :

cf() {
  cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}

아래와 같은 스크립트에 단축키를 지정할 수도 있습니다.

기존 탭을 재사용하거나 새 창을 작성하십시오 (터미널).

tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
    if (exists window 1) and not busy of window 1 then
        do script "cd " & quoted form of p in window 1
    else
        do script "cd " & quoted form of p
    end if
    activate
end tell

기존 탭을 재사용하거나 새 탭을 작성하십시오 (터미널).

tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
    if not (exists window 1) then reopen
    activate
    if busy of window 1 then
        tell application "System Events" to keystroke "t" using command down
    end if
    do script "cd " & quoted form of p in window 1
end tell

항상 새 탭을 작성하십시오 (iTerm 2).

tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
    if exists current terminal then
        current terminal
    else
        make new terminal
    end if
    tell (launch session "Default") of result to write text "cd " & quoted form of p
    activate
end tell

처음 두 스크립트는 10.7에서 추가 된 서비스와 비교하여 몇 가지 장점이 있습니다.

• 10.9부터는 입력으로 폴더를받는 서비스가 열보기의 서비스 메뉴에 나열되지 않는 버그가 있습니다. 폴더 서비스의 새 터미널 탭에 바로 가기 키를 할당하면 열보기에서 작동하지 않습니다.
• 먼저 폴더를 선택하지 않고 제목 표시 줄의 폴더를 사용합니다.
• 명령을 실행하거나 매뉴얼 페이지를 표시하거나 emacs를 실행하는 등 바쁘지 않은 경우 맨 앞 탭을 재사용합니다.

10.7 또는 10.8을 사용하는 경우 다음으로 변경 tell application "Finder" to set p to POSIX path of (insertion location as alias)하십시오.

tell application "Finder"
    if exists Finder window 1 then
        set p to POSIX path of (target of Finder window 1 as alias)
    else
        set p to POSIX path of (path to desktop)
    end if
end tell

10.7 및 10.8에는 버그가 있지만 (10.9 또는 10.6은 아님) 마지막으로 포커스를 다른 응용 프로그램으로 옮긴 후 생성 된 창을 무시하고 insertion location속성을 가져올 때 Finder가 Finder를 무시하는 버그가 있습니다.

답변