확인. 해결책이있을 수 있습니다. 나는 찾고 시도 /savecred의 매개 변수 net use만이 제대로 그래서 여기에 작동시킬 수 없습니다 또 다른 방법입니다 :

VPN 연결을 끊은 후 Explorer가 지연되는 문제가있었습니다.
따라서 연결을 끊은 후에 탐색기에서 드라이브를 숨기지 마십시오.

탐색기에서 드라이브를 숨기는 레지스트리 키가 있습니다.

HKEY_xxx\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer\NoDrives

및 HKEY_xxx 둘 수 있습니다 HKEY_LOCAL_MACHINE와 HKEY_CURRENT_USER.

이 게시물 아래에는 어떤 가치 NoDrives가 있어야 하는지에 대한 요약 이 있습니다.
(드라이브 번호를 추가하십시오).

계산을 직접 수행 할 필요가없는 작은 배치 파일을 만들었습니다.
‘토글’배치 파일입니다.

“My VPN”에 연결하려면 한 번만 실행하십시오. 드라이브 I, J 및 K
연결을 끊고 숨기려면 다시 실행하십시오 .

이것을 두 개의 배치 파일로 쉽게 분할 할 수 있지만 요점을 알 수 있습니다 … NoDrives배치를 계산하지 않고 자신 의 수를 설정하면 이 배치 파일을 단순화 할 수도 있습니다 .

관리자 권한으로 실행해야합니다. (자동으로 올릴 수는 있지만 매우 고급입니다)

당신이 키를 자신에게 권한을 부여 할 경우, NoDrives당신은 하지 않는 관리자 권한으로이 작업을 실행해야합니다. 를 열고이 regedit.exe키를 찾은 다음 “편집> 권한”을 클릭하고이 키에 대해 “모든 권한”을 부여하십시오.

@echo off
:: ------------------------
set MyVPN="My VPN"
:: ------------------------
rasdial | findstr %MyVPN% 1>nul
If %ERRORLEVEL% == 0 goto disconnect

:connect
echo ============================================================
echo connecting to %MyVPN%
echo ============================================================
rasdial %MyVPN%
:: This is easy. We just set 0 in NoDrives
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer /v NoDrives /T REG_DWORD /d 0 /f

goto :end

:disconnect
echo ============================================================
echo disconnecting from %MyVPN%
echo ============================================================
rasdial %MyVPN% /disconnect

:: ------------------------------------------------------------------
:: This is harder. We need to determine what value NoDrives should be
:: ------------------------------------------------------------------
Setlocal EnableDelayedExpansion

:: ------------------------
:: Set here your VPN drives
:: ------------------------
set drives='I J K'

:: ------------------------
:: Calculation to determine the value
:: ------------------------
set drive_value=1
set NoDrives=0
for %%c in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  echo.%drives% | findstr "%%c" 1>nul
  if !ERRORLEVEL! == 0 set /a NoDrives+=drive_value
  set /a drive_value="drive_value<<1"
)
echo Seting NoDrives to %NoDrives%
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer /v NoDrives /T REG_DWORD /d %NoDrives% /f
endlocal

:end
pause

참고 :
드라이브를 숨기거나 다시 보려면 Windows 탐색기를 닫았다가 다시 열어야합니다.

에 대한 설정 NoDrives:

HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer\NoDrives
HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer\NoDrives

     Decimal       Hex
A:         1         1
B:         2         2
C:         4         4
D:         8         8
E:        16        10
F:        32        20
G:        64        40
H:       128        80
I:       256       100
J:       512       200
K:      1024       400
L:      2048       800
M:      4096      1000
N:      8192      2000
O:     16384      4000
P:     32768      8000
Q:     65536     10000
R:    131072     20000
S:    262144     40000
T:    524288     80000
U:   1048576    100000
V:   2097152    200000
W:   4194304    400000
X:   8388608    800000
Y:  16777216   1000000
Z:  33554432   2000000

답변