Word에서 대체 제목 스타일 만들기 전체 페이지 너비가 아닌

테두리가 있지만 전체 페이지 너비가 아닌 머리글로 Word 문서의 스타일을 지정하고 싶습니다.

이것과 비슷한 것 :
경계에있는 제목, 왼쪽 정렬

트릭은 홀수 페이지에서 머리글을 왼쪽 대신 오른쪽에 정렬하고 싶습니다.

경계에있는 제목, 오른쪽 정렬

물론 왼쪽 정렬과 오른쪽 정렬의 두 가지 스타일을 가질 수는 있지만 어느 페이지에 있는지주의해야하며 다른 페이지로 내용을 이동시키는 내용을 추가 할 때 모든 스타일을 변경해야합니다 .

페이지에 따라 스타일을 설정할 수있는 방법이 있습니까? 헤더로 쉽게 할 수 있습니다. 콘텐츠를위한 방법이 있다고 확신합니다.

답변

제목을 설정하는 데 사용할 수있는 기능을 알지 못합니다. 대체 옵션은 매크로 일 수 있습니다.

아래 코드는 문서의 모든 단락을 거치며 각 제목 스타일 (개요 수준이 1보다 크거나 같음) 인 경우 페이지 번호에 따라 정렬 및 세로 테두리를 설정합니다. 

Sub alignHeaders()
    Dim i As Integer
    Dim p As Paragraph
    Dim IndentAmount As Single

    IndentAmount = CentimetersToPoints(10)

    Application.ScreenUpdating = False

    For Each p In ActiveDocument.Paragraphs
        With p
            If .OutlineLevel <> wdOutlineLevelBodyText Then
                If .Range.Information(wdActiveEndAdjustedPageNumber) Mod 2 = 1 Then
                    With .Range.ParagraphFormat
                        .LeftIndent = 0
                        .RightIndent = IndentAmount
                        .Borders(wdBorderLeft).LineStyle = wdLineStyleNone
                        .Borders(wdBorderRight).LineStyle = wdLineStyleSingle
                    End With
                Else
                    With .Range.ParagraphFormat
                        .RightIndent = 0
                        .LeftIndent = IndentAmount
                        .Borders(wdBorderLeft).LineStyle = wdLineStyleSingle
                        .Borders(wdBorderRight).LineStyle = wdLineStyleNone
                    End With
                End If
            End If
        End With
    Next p

    Application.ScreenUpdating = True
End Sub

매크로 실행

  • 당신은 그것을 둘 수 있습니다
    • 당신의 정상에서 .dotm
    • 이 형식을 사용하려는 문서에서
    • 헤더 스타일을 정의하고이 매크로를 배치 할 템플릿 파일을 만들 수 있습니다
  • 필요할 때 매크로를 실행하기 위해 핫키를 할당 할 수 있습니다
  • 인쇄 / 저장 전에 매크로가 자동으로 실행되도록 설정할 수도 있습니다. 유용한 지침이 있습니다 (경고 : 매크로를이 방법으로 설정하고 normal.dotm에있는 경우 저장 / 인쇄하는 모든 파일을 포맷합니다!)

추가 참고 사항 :이 매크로는 이제 목표를 변경하려는 개요에 따라 개요 수준이 비어 있지 않은 모든 단락의 서식을 변경합니다. 개요 수준 (예 🙂 대신 스타일 이름을 확인 If Left(.Style,7)="Heading"하는 것은 확실한 해결책이지만 스타일 이름은 언어에 따라 다른 언어에서는 작동하지 않습니다.

답변