다음 방법은 설명 된 해결 방법을 사용합니다. 이리 과 이리 VBA에 정의 된 워크 시트 함수를 사용하여 다른 셀의 값을 설정할 수 있습니다.

사용자 정의 함수는 대상 변수의 주소와 해당 셀을 설정할 값을 전역 변수에 저장합니다. 그런 다음 워크 시트가 다시 계산 될 때 트리거되는 매크로는 전역 변수를 읽고 대상 셀을 지정된 값으로 설정합니다.

사용자 정의 함수의 사용은 간단합니다.

  =SetCellValue(target_cell, value)

어디에 target_cell 워크 시트의 셀에 대한 문자열 참조 (예 : ‘A1’) 또는 그러한 참조로 평가되는 표현식입니다. 여기에는 다음과 같은 표현식이 포함됩니다. =B14 여기서 B14의 값은 “A1″입니다. 함수는 유효한 표현식에서 사용될 수 있습니다.

SetCellValue 값이 대상 셀에 성공적으로 기록되면 1을 반환하고 그렇지 않으면 0을 반환합니다. 대상 셀의 이전 내용을 덮어 씁니다.

세 가지 코드가 필요합니다.

• 코드 정의 SetCellValue 그 자체
• 워크 시트 계산 이벤트에 의해 트리거되는 매크로. 과
• 효용 함수 IsCellAddress 보장하기 위해 target_cell 유효한 셀 주소입니다.

SetCellValue 함수에 대한 코드

이 코드는 통합 문서에 삽입 된 표준 모듈에 붙여 넣어 야합니다. 이 모듈은 Visual Basic 편집기의 메뉴를 통해 삽입 할 수 있습니다. Visual Basic ~로부터 Developer 탭의 탭.

  Option Explicit

  Public triggerIt As Boolean
  Public theTarget As String
  Public theValue As Variant

  Function SetCellValue(aCellAddress As String, aValue As Variant) As Long

      If (IsCellAddress(aCellAddress)) And _
             (Replace(Application.Caller.Address, "$", "") <> _
              Replace(UCase(aCellAddress), "$", "")) Then
          triggerIt = True
          theTarget = aCellAddress
          theValue = aValue
          SetCellValue = 1
      Else
          triggerIt = False
          SetCellValue = 0
      End If

  End Function

Worksheet_Calculate 매크로 코드

이 코드는 사용할 워크 시트의 코드에 포함되어야합니다. SetCellValue. 가장 쉬운 방법은 워크 시트의 탭을 마우스 오른쪽 버튼으로 클릭하는 것입니다. Home 보기, 선택 View Code그런 다음 편집기 창에 코드를 붙여 넣습니다.

  Private Sub Worksheet_Calculate()

      If Not triggerIt Then
          Exit Sub
      End If
      triggerIt = False
      On Error GoTo CleanUp
      Application.EnableEvents = False
      Range(theTarget).Value = theValue
  CleanUp:
      Application.EnableEvents = True
      Application.Calculate

  End Sub

IsCellAddress 함수에 대한 코드

이 코드는 동일한 모듈에 붙여 넣을 수 있습니다. SetCellValue 암호.

  Function IsCellAddress(aValue As Variant) As Boolean

      IsCellAddress = False

      Dim rng As Range           ' Input is valid cell reference if it can be
      On Error GoTo GetOut       ' assigned to range variable
      Set rng = Range(aValue)
      On Error GoTo 0

      Dim colonPos As Long            'convert single cell "range" address to
      colonPos = InStr(aValue, ":")   'single cell reference ("A1:A1" -> "A1")
      If (colonPos <> 0) Then
          If (Left(aValue, colonPos - 1) = _
                Right(aValue, Len(aValue) - colonPos)) Then
              aValue = Left(aValue, colonPos - 1)
          End If
      End If

      If (rng.Rows.Count = 1) And _
          (rng.Columns.Count = 1) And _
          (InStr(aValue, "!") = 0) And _
          (InStr(aValue, ":") = 0) Then
          IsCellAddress = True
      End If                          'must be single cell address in this worksheet
      Exit Function

  GetOut:

  End Function

답변

=IF(ISNUMBER(FIND("green",B5)),"Text A","")

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("B5")) Is Nothing Then
    If InStr(1, Target, "green", vbTextCompare) Then
        Target.Offset(0, 1) = "Text A"
    End If
End If
End Sub