내가 찾은 roryok 의 대답은 매우 도움이 될, 그는 제공 batch script에 대한 Windows그 당신을 수 있도록 drag-&-drop빠르고 자동화 된 보관 파일입니다.

이 스크립트를 사용하려면 .bat확장명으로 저장 한 다음 파일 및 / 또는 폴더를 배치 파일 ( 또는 배치 파일 의 바로 가기)로 끌어다 놓을 수 있습니다 .

.zip파일은 소스 파일과 동일한 디렉토리에 작성됩니다.
( @ 스크립트에서 대상을 변경할 수 있지만archivePath )

쉽게 사용자 정의 및 전반적인 기능을 향상시키기 위해 업데이트 한 내용 :

• 명명 된 변수 추가
• 구현 for주어진 인수를 반복하는 것을 루프
  ( 함께이 delayedexpansion런타임 변수를 허용하는 )
• if차별화 할 조건 추가 files및folders
  • 이를 통해 아카이브 내에 상위 폴더를 묶지 않고 폴더 내용을 아카이브에 직접 추가 할 수 있습니다
    ( EG :   \archive.zip\file.txt   VS   \archive.zip\parent_folder\file.txt )
• 실패한 인스턴스를 표시하거나 오류가없는 경우 성공 메시지를 표시하기 위해 오류 로그를 추가했습니다.

@Echo OFF
SetLocal EnableDelayedExpansion



Rem //  7-Zip Executable Path
Set sevenZip="C:\Program Files\7-Zip\7z.exe"



Rem // START: NewLine Variable Hack
Set newLine=^


Rem // END: NewLine Variable Hack !! DO NOT DELETE 2 EMPTY LINES ABOVE !!



Rem //  Set ErrorLog Variables
Set errorCount=0
Set separator=--------------------------------------------------------
Set errorLog=!newLine!!newLine!!separator!!newLine!!newLine!
Set errorPrefix=ERROR @:
Set successMessage=All Files Were Successfully Archived



Rem //  Loop Through Each Argument
SetLocal DisableDelayedExpansion
for %%x in (%*) do (

    Rem //  Use Current Argument To set File, Folder, & Archive Paths
    SetLocal DisableDelayedExpansion
    Set filePath="%%~x"
    Set directoryFiles="%%~x\*"
    Set archivePath="%%~x.zip"
    SetLocal EnableDelayedExpansion

    Rem //  Source Is A Folder
    if exist !directoryFiles! (
            Set sourcePath=!directoryFiles!
    )

    Rem //  Source Is A File
    if not exist !directoryFiles! (
            Set sourcePath=!filePath!
    )

    Rem //  Print Separator To Divide 7-Zip Output
    echo !newLine!!newLine!!separator!!newLine!!newLine!

    Rem //  Add Files To Zip Archive
    !sevenZip! A -TZIP !archivePath! !sourcePath!

    Rem //  Log Errors
    if ErrorLevel 1 (
        Set /A errorCount=errorCount+1
        Set errorLog=!errorLog!!newLine!!errorPrefix!!sourcePath!
    )
)



Rem //  Print ErrorLog
if !errorCount!==0 (
    Set errorLog=!errorLog!!newLine!!successMessage!
)
Echo !errorLog!!newLine!!newLine!!newLine!



Rem //  Keep Window Open To View ErrorLog
pause

답변