그러나 @Matt Love의 Automator 솔루션은 여러 페이지 PDF 파일을 개별 TIFF로 변환하지 않습니다. 하나는 PDF 파일을 이미지로 변환하고 다른 하나는 이미지 파일 형식을 변경하기 위해 두 개의 별도 Automator 워크 플로우를 실행해야합니다. 대안으로, Mac OS X의 내장 이미지 이벤트와 함께 AppleScript 사용을 고려할 수 있습니다 .

간단한 Automator 워크 플로와 달리 아래에 제공된 스크립트 (구문 색 버전은 여기 )는 이미지 와 PDF 파일을 TIFF 로 변환 하고 오류보고를 수행 하며 일부 파일을 처리하지 못할 때 오류가 발생 하지 않습니다. 스크립트를 실행하기 전에 Finder에서 처리 할 파일을 선택하십시오.

편집 : 여러 페이지 PDF의 경우 1 페이지 만 변환됩니다.

# this script converts all PDFs and images selected in Finder
# to the TIFF format and appends .tif to the file name

set t to (time of (current date))
tell application "Finder" to set sel to selection
set errors to {}
tell application "Image Events"
    repeat with img_file in sel
        try
            set img_file to img_file as text
            set img to open img_file
            save img as TIFF in (img_file & ".tif")
            if (class of result) is not file then error "could not convert to TIFF"
            close img
        on error errMsg
            set errors to errors & ((name of (info for (img_file as alias)) & ": " & errMsg & "\n") as text)
            try
                close img
            end try
        end try
    end repeat
end tell

# error report
set errcount to length of errors
set msg to (((length of sel) - errcount) as text) & " files converted to TIFF in " & ¬
    (((time of (current date)) - t) as text) & " seconds.\n\n"
if errors is not {} then
    set msg to msg & errcount & " errors occurred: \n" & errors as text
end if
display dialog msg

답변

for i in *; do magick convert -density 300 ./$i -depth 8 ./$i.tiff; done

sips -s format tiff input.pdf --out output.tiff