불행히도 6 년 후 Windows 10에서 동일한 문제가 발생했으며 최근 Windows 10 업데이트에서 일부 바로 가기 / 프로그램이 더 이상 dem 등하 지 않음을 발견했습니다
! 특히 같은 세션에 여러 단축키가있는 퍼티.

그래서 AutoHotKey를 사용 하고 LifeHacker 의이 기사를 기반 으로이 스레드에서 공유되는 기능을 수정하여 INI 파일을 사용하여 각 바로 가기를 추적합니다. 이것은 개인적으로 유지하고 싶은 기능인 다른 서버에 화면이나 SSH를 사용하면 퍼티에서 변경 될 수 있으므로 각 프로그램의 Windows 제목을 사용하지 않습니다!

INI 파일에서 UniqueName 항목을 제거하기위한 바로 가기를 작성할 수있는 “DeleteINIEntry ()”함수도 포함되어 있습니다. 또는 파일을 수동으로 편집하고 변경할 수 있습니다.

INIFilePath := "C:\Temp\AHK.ini"

RunOrSwitchWin( UniqueName, AppPath )
{
    global INIFilePath
    IniRead, TargetID, %INIFilePath%, windowids, %UniqueName%
    ActiveID := WinExist("A")

    ; cannot use '=' here as comparing an integar to string doesn't work well
    IfEqual TargetID, %ActiveID%
    {
        WinMinimize
        return
    }

    WinGet, AllIDs, list

    Loop, %AllIDs%
    {
        this_id := AllIDs%A_Index%

        ifEqual TargetID, %this_id%
        {
            DllCall("SwitchToThisWindow", "UInt", this_id, "UInt", 1)
            return
        }
    }

    run, %AppPath%,,, CurrentPID
    WinWait ahk_pid %CurrentPID%
    IniWrite, % WinExist("A"), %INIFilePath%, windowids, %UniqueName%

   return
}

DeleteINIEntry()
{
    global INIFilePath
    InputBox, UniqueName, Delete INI Entry, Enter UniqueName

    If ErrorLevel = 0
        IniDelete, %INIFilePath%, windowids, %UniqueName%

    return
}

^!3::DeleteINIEntry()

; Putty shortcuts.
; ^!1 is NOT idempotent and will run it over and over again.
^!1::run "C:\Program Files\PuTTY\putty.exe"
^!2::RunOrSwitchWin( "session1", "C:\Program Files\PuTTY\putty.exe -load session1" )

창을 최소화하지 않으려면 WinMinimize 줄에 주석을 추가하고 (; 앞에 붙임) 단순히 활성 창에 계속 집중합니다.

답변