당신은 자바 스크립트 스크롤 양을 설정하십시오.

정의 된 비율로 스크롤을 조정하려면 :

set myURL to "https://weather.com/weather/hourbyhour/l/12345"
set scrollAmount to "16" --- % down the page

tell application "Google Chrome"
    activate
    tell front window to set curTab to make new tab at after (get active tab) with properties {URL:myURL}
    tell curTab
        repeat while (loading)
            delay 1
        end repeat
        -- set the vertical scroll
        execute javascript "h=document.documentElement.scrollHeight-document.documentElement.clientHeight; window.scrollTo(0,h*" & scrollAmount & "/100)"
    end tell
end tell

페이지의 요소 맨 위에서 세로 스크롤을 조정하려면 스크립트에서 다음을 사용하여 요소를 가져올 수 있습니다. document.getElementById('twc-scrollabe') twc-scrollable 테이블의 식별자입니다.

그 후, 자바 스크립트 루프를 사용하여 페이지의 표 상단을 가져옵니다.

set myURL to "https://weather.com/weather/hourbyhour/l/12345"
tell application "Google Chrome"
    activate
    tell front window to set curTab to make new tab at after (get active tab) with properties {URL:myURL}
    tell curTab
        repeat while (loading)
            delay 1
        end repeat
        -- scroll to the top of the table
        execute javascript "e=document.getElementById('twc-scrollabe');tTop=0; do {tTop +=e.offsetTop || 0; e=e.offsetParent} while(e); window.scrollTo(0,tTop);"
    end tell
end tell

이 문제 자바 스크립트 (다른 URL에서) 페이지의 소스에서 식별자를 찾아서 스크립트에서 변경해야합니다. 요소에 식별자가 없으면 다른 메소드를 사용하여 요소를 가져와야합니다. JavasScript 코드는 사이트의 페이지에.

답변

set myURL to "https://weather.com/weather/hourbyhour/l/12345"

tell application "Google Chrome"
    set bounds of front window to {0, 23, 1440, 850}
    tell front window to make new tab at after (get active tab) with properties {URL:myURL}
    repeat while (loading of active tab of front window is true)
        delay 1
    end repeat
    activate
    tell application "System Events"
        repeat 9 times
            key code 125 -- # Down Arrow
            delay 0.1
        end repeat
    end tell
end tell